(defun ap/org-tree-to-indirect-buffer (&optional arg)
    "Create indirect buffer and narrow it to current subtree.
The buffer is named after the subtree heading, with the filename
appended.  If a buffer by that name already exists, it is
selected instead of creating a new buffer."
    (interactive "P")
    (let* ((new-buffer-p)
           (buffer-name (let ((heading (nth 4 (org-heading-components))))
                          ;; FIXME: I think there's an Org function that does this, but I can't find it.
                          (concat (if (string-match org-bracket-link-regexp heading)
                                      ;; Heading is an org link; use link name
                                      ;; TODO: but what if only part of the heading is?
                                      (match-string 3 heading)
                                    ;; Not a link; use whole heading
                                    heading)
                                  "::" (buffer-name))))
           (new-buffer (or (get-buffer buffer-name)
                           (prog1 (condition-case nil
                                      (make-indirect-buffer (current-buffer) buffer-name 'clone)
                                    (error (make-indirect-buffer (current-buffer) buffer-name)))
                             (setq new-buffer-p t)))))
      (switch-to-buffer new-buffer)
      (when new-buffer-p
        (rename-buffer buffer-name)
        (org-narrow-to-subtree))))

  (advice-add 'org-tree-to-indirect-buffer :override 'ap/org-tree-to-indirect-buffer)